/*
   /#############################################################\
  <#/-----------------------------------------------------------\#>
  <#|                                                           |#>
  <#|   |###\   /###\  |#   #| Persistence Of Vision Ray Tracer |#>
  <#|   |# >#| |#/ \#| |#   #|     Freeware Version 3.0         |#>
  <#|   |###/  |#   #| |#\ /#|     POV Format Source Code       |#>
  <#|   |#|    |#\ /#|  \#^#/      Date: January 4, 1997        |#>
  <#|   |#| o   \###/ o  \#/ o     Author: Joseph P. Durbin     |#>
  <#|                                                           |#>
  <#| +-----------------< Scene Description >-----------------+ |#>
  <#| |                                                       | |#>
  <#| | Graphing Routine For Clock Function                   | |#>
  <#| |                                                       | |#>
  <#| | Replace Functions Below To Graph                      | |#>
  <#| |                                                       | |#>
  <#| |                                                       | |#>
  <#\ +-------------------------------------------------------+ /#>
   \#############################################################/
*/


#include "colors.inc"
#include "stones.inc"

#declare Camera1=
  camera {
    location <.5,.4,-.95>
    rotate <-20,10,0>
    look_at <.5,.45,0>
  }

camera {
  Camera1
}

light_source {  <.5,.5,-5>  color White}

union {
  cylinder { <-.025,-.025,0>, <1.025,-.025,0>, .025 }
  cylinder { <-.025,-.025,0>, <-.025,1.025,0>, .025 }
  cylinder { <-.025,1.025,0>, <1.025,1.025,0>, .025 }
  cylinder { <1.025,1.025,-.025>, <1.025,-.025,0>, .025 }
  sphere { <-.025,-.025,0>, .025 }
  sphere { <-.025,1.025,0>, .025 }
  sphere { <1.025,-.025,0>, .025 }
  sphere { <1.025,1.025,0>, .025 }
  texture { T_Stone21 }
}

cylinder { <.5,0,0>, <.5,1,0>, .01 pigment {rgb<1,1,1>}}
cylinder { <.25,0,0>, <.25,1,0>, .005 pigment {rgb<.8,.8,.8>}}
cylinder { <.75,0,0>, <.75,1,0>, .005 pigment {rgb<.8,.8,.8>}}
cylinder { <1,.5,0>, <0,.5,0>, .01 pigment {rgb<1,1,1>}}
cylinder { <1,.25,0>, <0,.25,0>, .005 pigment {rgb<.8,.8,.8>}}
cylinder { <1,.75,0>, <0,.75,0>, .005 pigment {rgb<.8,.8,.8>}}

//////////////////////////////////////////////////////////////////////////////////
/////////////  Graph Functions Below (Function Must Be Written Twice)/////////////
//////////////////////////////////////////////////////////////////////////////////
#declare Step=.005
#declare C=Step
#declare V=(0+((.5*sin(2*4*0*pi))+.5))/2  // Replace This Function Using '0' for all values of 'clock'
#while (C<=1+Step)
  #declare OV=V
  #declare V=(C+((.5*sin(2*4*C*pi))+.5))/2  // Replace This Function Using 'C' for all values of 'clock'
  cylinder { <C-Step,OV,0>,<C,V,0>, .015 texture{ T_Stone18}} //pigment {rgb<.8,0,0>}}
  #declare C=C+Step
#end